#!/usr/bin/perl

 # ***** BEGIN LICENSE BLOCK *****

 # Version: MPL 1.1

 #

 # The contents of this file are subject to the Mozilla Public License Version

 # 1.1 (the "License"); you may not use this file except in compliance with

 # the License. You may obtain a copy of the License at

 # http://www.mozilla.org/MPL/

 #

 # Software distributed under the License is distributed on an "AS IS" basis,

 # WITHOUT WARRANTY OF ANY KIND, either express or implied. See the License

 # for the specific language governing rights and limitations under the

 # License.

 #

 # The Original Code is TomTom HOME build automation.

 #

 # The Initial Developer of the Original Code is

 # Wladimir Palant <trev@adblockplus.org>.

 # Portions created by the Initial Developer are Copyright (C) 2008

 # the Initial Developer. All Rights Reserved.

 #

 # Contributor(s):

 #

 # ***** END LICENSE BLOCK *****

 use strict;

 use warnings;

 die "Usage: $^X $0 directory\n" unless @ARGV;

 my $failure = 0;

 processDir($ARGV[0]);

 exit $failure;

 sub processDir

 {

     my $dir = shift;

     opendir(local *DIR, $dir);

     foreach my $file (readdir(DIR))

     {

         next if $file =~ /^\./;

         my $path = "$dir/$file";

         if (-d $path)

         {

             processDir($path);

         }

         elsif ($file =~ /\.dtd$/)

         {

             processDTDFile($path);

         }

         elsif ($file =~ /\.properties$/)

         {

             processPropertiesFile($path);

         }

     }

     closedir(DIR);

 }

 sub processDTDFile

 {

     my $file = shift;

     my $data = validateUTF8($file);

     return unless defined $data;

     my $S = qr/[\x20\x09\x0D\x0A]/;

     my $Name = qr/[A-Za-z_:][\w.\-:]*/;

     my $Reference = qr/&$Name;|&#\d+;|&#x[\da-fA-F]+;/;

     my $PEReference = qr/%$Name;/;

     my $EntityValue = qr/"([^%&"]|$PEReference|$Reference)*"|'([^%&']|$PEReference|$Reference)*'/;

     my $SystemLiteral = qr/"[^"]*"|'[^']*'/;

     my $ExternalID = qr/SYSTEM$S+$SystemLiteral/;

     my $EntityDef = qr/$EntityValue|$ExternalID/;

     my $PEDef = qr/$EntityValue|$ExternalID/;

     # Remove comments

     $data =~ s/<!--([^\-]|-[^\-])*-->//gs;

     # Remove entities

     $data =~ s/<!ENTITY$S+$Name$S+$EntityDef$S*>//gs;

     # Remove external entities

     $data =~ s/<!ENTITY$S+%$S+$Name$S+$PEDef$S*>//gs;

     # Remove external references

     $data =~ s/$PEReference//gs;

     # Remove spaces

     $data =~ s/^\s+//gs;

     $data =~ s/\s+$//gs;

     $data =~ s/\s+/ /gs;

     if ($data ne "")

     {

         $failure = 1;

         warn "$0: Unrecognized data in file $file: $data\n";

         return;

     }

 }

 sub processPropertiesFile

 {

     my $file = shift;

     my $data = validateUTF8($file);

     return unless defined $data;

     foreach my $line (split(/[\r\n]+/, $data))

     {

         if ($line !~ /^\s*[#!]/ && $line !~ /=/ && $line =~ /\S/)

         {

             # Not a comment, not a property, trash?

             $failure = 1;

             warn "$0: Unrecognized data in file $file: $line\n";

         }

     }

 }

 sub validateUTF8

 {

     my $file = shift;

     open(local *FILE, "<", $file);

     local $/;

     my $data = <FILE>;

     close(FILE);

     if ($data =~ /\xEF\xBB\xBF/)

     {

         $failure = 1;

         warn "$0: Byte Order Mark found in file $file\n";

         return;

     }

     unless (utf8::decode($data))

     {

         $failure = 1;

         warn "$0: File $file is not valid UTF-8\n";

         return;

     }

     return $data;

 }